Création et ouverture de modèles (Scripting)

Vous créez des modèles et ouvrez des modèles existants en utilisant les fonctions globales CreateModel() et OpenModel(). Le modèle actif est accessible via les propriété globale ActiveModelet ceux ouverts dans l'espace de travail sont disponibles via la collection globale Models.

Ce script crée un nouveau MOO ayant comme cible le langage Analysis, y crée des classes, les affiche dans le diagramme, puis enregistre le modèle et le referme :

Dim NouveauModele
set NouveauModele = CreateModel(PdOOM.Cls_Model, "Language=Analysis|Diagram=ClassDiagram|Copy")
If NouveauModele is Nothing then
 msgbox "Impossible de créer le modèle", vbOkOnly, "Error" ' Affiche un message d'erreur
Else
 output "Le modèle UML a été créé" ' Affichage d'un message dans la fenêtre Résultats
 NouveauModele.SetNameAndCode "MonMOO", "MonMOO" 'Initialisation des nom et code du modèle
 For idx = 1 to 12 'Création et affichage des classes
  Set obj=NouveauModele.Classes.CreateNew()
  obj.SetNameAndCode "C" & idx, "C" & idx
  Set sym=ActiveDiagram.AttachObject (obj)
 Next
 ActiveDiagram.AutoLayoutWithOptions(2)
 NouveauModele.Save "c:\temp\MonMOO.mom" ' Enregistrement du modèle
 NouveauModele.Close ' Fermeture du modèle
 Set NouveauModele = Nothing ' Libération de la dernière référence à l'objet pour libérer de la mémoire
End If

Ce script vérifie que le modèle qui vient d'être créé existe bien, et l'ouvert dans l'espace de travail :

Dim MonModele, FileName
FileName = "c:\temp\MonMOO.moo"
On Error Resume Next ' Omission du message d'erreur de scripting générique 
Set MonModele = OpenModel(FileName)
If MonModele is nothing then ' Affichage d'un message d'erreur
 msgbox "Impossible d'ouvrir le modèle :" + vbCrLf + FileName, vbOkOnly, "Error"  
Else ' Affichage d'un message dans la fenêtre Résultats
 output "Le MOO a été ouvert."  
End If