Consultation et modification des collections (Scripting)

La plupart de la navigation dans le métamodèle est effectuée en descendant depuis la racine du modèle via les collections d'objets vers les collections de sous-objets ou les objets associés. Un MOO contient une collection de classes et les classes contiennent des collections d'attributs et d'opérations. Vous pouvez obtenir des informations sur les membres d'une collection et naviguer sur eux par le biais de script, mais aussi ajouter, retirer et déplacer des objets dans la collection.

Pour parcourir les membres d'une collection, naviguez jusqu'à l'objet parent, puis utilisez une boucle For each. Ce script imprime les noms de toutes les tables contenues dans un MPD ouvert.

Dim MonModele
Set MonModele=ActiveModel
For each t in MonModele.Tables
    Output "* " & t.Name
Next

Lorsque vous parcourez une collection, les objets de la collection et les éventuels raccourcis vers des objets sont renvoyés indifféremment.

Remarque : Pour plus d'informations sur l'accès aux collections définies dans des extensions, voir Création et utilisation d'extensions (Scripting).

Les types de collection suivants sont affichés dans le métamodèle :

Compositions - contiennent des objets qui seront supprimés si le parent est supprimé. Par exemple, les collections PdPDM/Tables et PdPDM/Table/Columns sont des compositions.
Agrégations - référence des objets qui vont continuer à exister si leur parent est supprimé. Par exemple, la collection PdCommon/NamedObject/AttachedRules (héritée par la plupart des objets) est une agrégation.
Collections non ordonnées - contient des objets sans ordre significatif. Par exemple, la collection PdCDM/Entity/Relationships n'est pas ordonnée.
Collections ordonnées - contient des objets dans un ordre spécifié par l'utilisateur. Par exemple, la collection PdPDM/Table/Columns est ordonnée.
Collections en lecture seule - peuvent uniquement être parcourues. Par exemple, la collection globale Models (tous les modèles ouverts) est en lecture seule.

Les propriétés suivantes sont disponibles pour toutes les collections :

Count - Récupère le nombre d'objets contenus dans une collection.
Item[(index)] - Récupère l'élément spécifié dans la collection comme objet. Item(0) est le premier objet (et l'objet par défaut) et Item(-1) est le dernier objet.
MetaCollection - Récupère la métadéfinition de la collection comme un objet.
Kind - Récupère le type des objets que la collection peut contenir.
Source - Récupère l'objet sur lequel la collection est définie.

Les méthodes suivantes sont disponibles pour modifier les collections éditables :

CreateNew([typeobjet] et CreateNewAt(index[,typeobjet]) - [compositions uniquement] Crée un nouvel objet à la fin de la collection ou à l'index spécifié (par défaut, -1). Le paramètre typeobjet (par exemple, PdPDM.cls_Table) est pertinent uniquement si la collection prend en charge plusieurs sortes d'objets.
Add(objet) - Insère l'objet spécifié à la fin de la collection.
Insert([index][, objet]) - Insère l'objet spécifié dans la collection à l'index de position spécifié (par défaut, -1).
Move(index2, index1) - Déplace l'objet de la position index1 à la position index2 dans la collection.
Remove(objet[, delete = y|n]) et RemoveAt([index][, delete = y|n]) - Retire l'objet spécifié ou l'objet situé à l'index (par défaut, -1) spécifié de la collection. Dans le cas des agrégations, vous pouvez également spécifier la suppression de l'objet (les objets retirés d'une composition sont toujours supprimés).
Clear([delete = y|n]) - Retire tous objets de la collection et peut également les supprimer.

Le script suivant :

Crée un MPD,
Crée des objets dans les collections de composition non ordonnées Tables et BusinessRules, et
Ajoute certains objets à la collection d'agrégation ordonnée de T1 nommée AttachedRules, puis manipule cette collection :

Dim MonModele, t, r, sym
set MonModele = CreateModel(PdPDM.Cls_Model,"DBMS=SYASA12")
MonModele.SetNameAndCode "MonMPD" , "MonMPD"
'Créer des tables des règles
For idx = 1 to 12
   Set t=MonModele.Tables.CreateNew()
   t.SetNameAndCode "T" & idx, "T" & idx
   Set sym=ActiveDiagram.AttachObject (t)
   Set r=MonModele.BusinessRules.CreateNew()
   r.SetNameAndCode "RG" & idx, "RG" & idx
Next
ActiveDiagram.AutoLayoutWithOptions(2)
'Attacher des règles à Table 1
   Dim MaTable
   Set MaTable=MonModele.FindChildByName("T1",cls_table)
   For idx = 1 to 10
      MaTable.AttachedRules.Add(MonModele.FindChildByName("RG" & (idx),cls_businessrule))
   Next
'Imprimer la liste de règles attachées à Table 1
Output "Règles attachées à T1 (" & MaTable.AttachedRules.Count & ")"
For each r in MaTable.AttachedRules
    Output "* " & r.Name
Next
'Modifie les règles attachées par insertion, déplacement et suppression
MaTable.AttachedRules.Insert 3, MonModele.FindChildByName("RG12",cls_businessrule)
MaTable.AttachedRules.Move 5,0
MaTable.AttachedRules.Remove(MonModele.FindChildByName("RG6",cls_businessrule))
'Imprimer la liste de règles modifiée
Output "Règles modifiées attachées à T1 (" & MaTable.AttachedRules.Count & ")"
For each r in MaTable.AttachedRules
    Output "* " & r.Name
Next