DownloadFile

Syntax

void DownloadFile (string serverFile, boolean open)

Parameters

• serverFile – A string containing the name of the file on the application’s virtual file path on the Web server.
• open – A boolean that determines whether to access the file in open mode or download mode. Values are:
  • true — show the file directly in a browser window (open mode).
  • false — show a dialog box that lets the user open the file, save the file, or cancel the download operation (download mode).

Returns

None.

Examples

• – This example opens the file aaa.txt in download mode:

     #if defined PBWEBFORM then
  	     DownloadFile("c:\aaa.txt", false)
     #end if

  The download mode causes the File Download dialog box to appear, giving the user the choice of opening the file, saving the file, or cancelling the operation. The File Download dialog box shows the file name, the file type, the number of bytes in the file, and the name of the server that hosts the file.

• – This code opens a dialog box that allows users to select a directory and download multiple files from the same directory:

     string docpath, docname[]
     boolean lb_open
     integer i, li_cnt, li_rtn, li_filenum 
  
     lb_open = true //or false
     li_rtn = GetFileOpenName("Select File",  docpath, & 
        + docname[], "DOC", &
        + "Text Files (*.TXT),*.TXT," &
        + "Doc Files (*.DOC),*.DOC," &
        + "All Files (*.*), *.*", &
        "C:\Program Files\Sybase", 18)
     IF li_rtn < 1 THEN return
     li_cnt = Upperbound(docname)
     // if only one file is picked, docpath contains the 
     // path and file name
        if li_cnt = 1 then
           mle_1.text = string(docpath)
           #if defined PBWEBFORM then
           DownloadFile(string(docpath), lb_open)
        #end if
     else
        // if multiple files are picked, docpath contains 
        // the path only - concatenate docpath and docname
        for i=1 to li_cnt
           string s
           s = string(docpath) + "\" +(string(docname[i]))
           #if defined PBWEBFORM then
              DownloadFile(s, lb_open)
           #end if
           mle_1.text += s +"~r~n"
         next
      end if